nodemcu webserver + led villogás

nekem is az a bajom, hogy ez a rész a loop-ban

char c = client.read();

blokkolja a futást, hiszen vár arra hogy a weben valamit kapjon. gondoltam egy interrupt jó lehet, de olyan mintha itt csak hw interrupt lenne. csak GPIO-hoz lehet kötni interruptot és ahhoz adni handlert, de nekem valamifajta időzítő kellene, ami bizonyos időnkét a handlerre tenné a vezérlést. viszont nem találok sw interruptot, amit mondjuk időzíteni lehetne.

ráadásul a led villogtatása be-illetve kikapcsolása mellé azt is meg szeretném adni a webes felületen, hogy ha be van kapcsolva, akkor milyen frekvencián villogjon. ez megint csak egy időzítőért kiált és egy interruptért. Ha rányomok, hogy bekapcsol, akkor időzítőhöz rendeli a handlert, a handler meg vizsgálná a státuszt, ha LOW akkor HIGH-re állítja, ha HIGH, akkor LOW-ra így villogna és a beadott frekvencián, hiszen a megadott időben kerülne ide a vezérlés. ha OFF-ra kapcsolom, akkor törli az interruptot, mert akkor minek fusson.

létezik ilyen időzítőhöz köthető interrupt? Vagy ha nem akkor hogy lehet megoldani?

- töröltem mert rosszul használtam a válasz funkciót -

ez itt interrupt vezérelten működik és frankón villog ha bekapcsolom


#include <ESP8266WiFi.h>

// Add wifi access point credentiaals
const char* ssid     = "ssid";
const char* password = "password";


WiFiServer server(80);// Set port to 80


String header; // This storees the HTTP request



int led = D1;

bool led_state = false;

void blink_led()
{
  noInterrupts();
  //Serial.println("in blink_led interrupt. ");
  digitalWrite(led, led_state);
  led_state = !led_state;
  timer1_write(100000);
  interrupts(); 
}

void setup() {
  Serial.begin(115200);
 // Set the pinmode of the pins to which the LEDs are connected and turn them low to prevent flunctuations
  pinMode(led, OUTPUT);
  digitalWrite(led, LOW);
  //connect to access point
  WiFi.begin(ssid, password);
  Serial.print("Connecting to ");
  Serial.println(ssid);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());// this will display the Ip address of the Pi which should be entered into your browser
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // turns the GPIOs on and off
            if (header.indexOf("GET /led/on") >= 0) {
              Serial.println("led on");
              led_state = true;
              timer1_attachInterrupt(blink_led);
              timer1_isr_init();
              timer1_enable(TIM_DIV256, TIM_EDGE, TIM_SINGLE);
              timer1_write(100000);
              digitalWrite(led, HIGH);
            } else if (header.indexOf("GET /led/off") >= 0) {
              Serial.println("led off");
              led_state = false;
              timer1_detachInterrupt();
              timer1_disable();
              digitalWrite(led, LOW);
            }
       
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #77878A;}</style></head>");
            
            // Web Page Heading
            client.println("<body><h1>ESP8266 Web Server</h1>");
            
            // Display current state, and ON/OFF buttons for GPIO 5  
            //client.println("<p>LED - State " + led_state + "</p>");
            // If the green LED is off, it displays the ON button       
            if (!led_state) {
              client.println("<p><a href=\"/led/on\"><button class=\"button\">BLINKING</button></a></p>");
            } else {
              client.println("<p><a href=\"/led/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 
               
                        client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    
  
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}