gnuplot dolt betu

Helló!

Én a következő módon szoktam csinálni: A gnuplot pslatex output-ját használom, ekkor egy PS-t tartalmazó LaTeX állomány jön létre, ami köré már csak a normál LaTeX keretet kell megírni, abból egy PS-t létrehozni, a PS-ből pedig mondjuk a convert-tel már azt csinálsz, amit akarsz (akár jpeg-et is). Ja, a gnuplot-nak bármilyen LaTeX szekvenciát be lehet adni, amik a pslatex output-tal frankón működnek is (tehát nem érdemes a ps output korlátozott lehetőségeit használni). Mindjárt kiderítem, hogy kódokat hogyan lehet csatolni, s akkor írok példát is.
----------
Were antimatter present, its detection would be quite simple and straightforward. The most rudimentary detector suffices: simply place it down and wait. If the detector disappears, antimatter has been discovered - get out fast!

Én ezt használom nem tudom hogy megvan e? Neked szerintem hasznos

http://cleopatra.elte.hu/~mazsx/gnuplot/gnuplothowto.pdf

Na, szóval a következőkkel különböző hőmérsékletekhez tartozó Planck-görbéket lehet rajzolni:

A black-body-radiation-gnuplot.plt állomány:

h = 6.63e-34
c = 3.0e8
k = 1.38e-23
pi = 3.14159265
scale_y = 1.0e16

T1 = 3.0e3
T2 = 2.5e3
T3 = 2.0e3
T4 = 1.5e3
T5 = 1.0e3

set term pslatex
set output "black-body-radiation-gnuplot.tex"

set xlabel '$\nu \,\, [10^{14} \,\, \mbox{Hz}]$'
set ylabel '$u_\nu \,\, [10^{-14} \,\, \mbox{J}/\mbox{m}^3\mbox{Hz}]$'

set dummy nu
set xrange [0.0:7.5e14]
set format x "%0.1t"
set xtics 0.0,2.5e14,7.5e14
set mxtics 5
set yrange [0.0:2.3]
set format y "%3.1f"
set ytics 0.0,1.0,3.0
set mytics 5

set origin 0.0,0.0
set size 2.2,2.2
set size ratio 0.7

set label 1 '$3\,000 \,\, \mbox{K}$' at 2.0e14,2.15
set label 2 '$2\,500 \,\, \mbox{K}$' at 2.5e14,0.87
set label 3 '$2\,000 \,\, \mbox{K}$' at 2.2e14,0.40
set label 4 '$1\,500 \,\, \mbox{K}$' at 1.5e14,0.22
set label 5 '$1\,000 \,\, \mbox{K}$' at 1.0e14,0.10

plot scale_y*(8.0*pi*h/c**3)*(nu**3/(exp(h*nu/(k*T1))-1.0)) notitle with lines 1, \
     scale_y*(8.0*pi*h/c**3)*(nu**3/(exp(h*nu/(k*T2))-1.0)) notitle with lines 1, \
     scale_y*(8.0*pi*h/c**3)*(nu**3/(exp(h*nu/(k*T3))-1.0)) notitle with lines 1, \
     scale_y*(8.0*pi*h/c**3)*(nu**3/(exp(h*nu/(k*T4))-1.0)) notitle with lines 1, \
     scale_y*(8.0*pi*h/c**3)*(nu**3/(exp(h*nu/(k*T5))-1.0)) notitle with lines 1

A black-body-radiation.tex állomány:

\documentclass[12pt]{article}

\usepackage{t1enc}
\usepackage[latin2]{inputenc}
\usepackage[magyar]{babel}
\usepackage{lscape}

\pagestyle{empty}

\begin{document}

\begin{landscape}
\begin{figure}
\centering{
\input{black-body-radiation-gnuplot.tex}
}
\end{figure}
\end{landscape}

\end{document}

Használat:

$ cat black-body-radiation-gnuplot.plt | gnuplot # eredmény: black-body-radiation-gnuplot.tex
$ latex black-body-radiation; dvips black-body-radiation # eredmény: black-body-radiation.ps

Ahogyan az előzőekben mondtam, a postscript állományból például az ImageMagick convert-tel bármit, akár jpg állományt is elő tudsz állítani.

Remélem, segített! Üdv!

----------
Were antimatter present, its detection would be quite simple and straightforward. The most rudimentary detector suffices: simply place it down and wait. If the detector disappears, antimatter has been discovered - get out fast!