Pici szkriptelés - segítségkérés .desktop fájlokhoz

ez remek
és hol akadtál el?
t

Ugye nem azt akarod, hogy ezt most irja meg neked valaki? Mert az mar had ne mondjam mi lenne. De ha nem igy van, akkor miert nem irtad le, hogy mi nem megy, es miben kellene segiteni?

#!/usr/bin/perl

use strict;

sub file_list {
  my($dir) = @_;
  opendir( my $d, $dir);
  my @fn = grep { !/^\.\.?$/ } readdir($d);
  closedir($d);

  my @res;
  while( my $fn = shift(@fn) ){
    $fn = $dir.'/'.$fn;
    push( @res, file_list( $fn ) ) if( -d $fn );
    push( @res, $fn              ) if( -f $fn && $fn =~ /\.desktop$/i );
  } 

  return @res;
}

#

open( OUT, '>:utf8', 'desktop.out' ); print OUT "\x{feff}";

my @files = file_list('.');
while( my $fn = shift(@files) ){
#  print STDERR 'fajl: ', $fn, "\n";
  open( IN, '<:utf8', $fn );
  my %text  = ();
  my $sect  = '';
  while( my $sor = <IN> ){
    chomp($sor);
    if( $sor =~ /^\[([^\]]*)\]\s*$/ ){
      $sect = $1;
    }
    elsif( $sor =~ /^(Comment|Generic.*?|Name)(\[[^\]]*\])?=(.*)$/i ){
      my ( $field, $lang, $val ) = ( $1, $2 || '', $3 );

      if( $lang =~ /^(\[hu\])?$/i ){
        $text{$sect}{$field}{$lang} = $val;
      }
    }
  }

  my $fn_print = 1;
  foreach my $s (sort keys %text){
    my $s_print = 1;
    foreach my $f (sort keys %{$text{$s}}){
      if( !exists( $text{$s}{$f}{'[hu]'} ) ){
        print OUT "file: $fn\n" if( $fn_print ); $fn_print = 0;
        print OUT "[$s]\n"      if( $s_print  ); $s_print  = 0;
        print OUT $f, '=', $text{$s}{$f}{''}, "\n";
      }
    }
    print OUT "\n" unless( $s_print );
  }

  close(IN);
}

close( OUT );

#

Ilyen fájlt állít elő:

file: /usr/share/applications/fedora-abiword.desktop
[Desktop Entry]
Comment=AbiWord Word Processor
GenericName=Word Processor
Name=AbiWord

file: /usr/share/applications/fedora-beryl-manager.desktop
[Desktop Entry]
Comment=Setup Beryl
Name=Beryl Manager

file: /usr/share/apps/kipiplugin_htmlexport/themes/classic/classic.desktop
[Desktop Entry]
Comment=A port of the old HTML Export plugin theme
Name=Classic

[X-HTMLExport Author]
Name=AurĂclien Gâteau

[X-HTMLExport Parameter bgColor]
Name=Background Color

[X-HTMLExport Parameter fgColor]
Name=Foreground Color

[X-HTMLExport Parameter fontSize]
Name=Font Size

[X-HTMLExport Parameter imgBorderColor]
Name=Image Border Color

[X-HTMLExport Parameter imgBorderSize]
Name=Image Border Size

[X-HTMLExport Parameter linkColor]
Name=Link Color

[X-HTMLExport Parameter thumbnailPerRow]
Name=Thumbnails per row

[X-HTMLExport Parameter visitedLinkColor]
Name=Visited Link Color

A szövegek módosítás után visszaírhatóak az eredeti fájlokba, persze '[hu]' jelöléssel ellátva.

Ilyen lett a visszaírás:

#!/usr/bin/perl

use strict;

my %forditas;

sub noesc {
  my ($str) = @_;
  $str =~  s/\\"/"/g;
  return $str;
}

sub PO_betoltes {
  my ( $po_fn, $mezo ) = @_;
  open( PO, '<:raw', $po_fn );
  my $msgid;
  while( my $sor = <PO> ){ 
    chomp($sor);
    if( $sor =~ /^msgid "(.+)"/ ){
      $msgid = noesc($1);
    }
    elsif( $sor =~ /^msgstr "(.+)"/ ){
      $forditas{$mezo}{$msgid} = noesc($1);
    }
  }
  close( PO );
}

sub file_list {
  my($dir) = @_;
  opendir( my $d, $dir);
  my @fn = grep { !/^\.\.?$/ } readdir($d);
  closedir($d);

  my @res;
  while( my $fn = shift(@fn) ){
    $fn = $dir.'/'.$fn;
    push( @res, file_list( $fn ) ) if( -d $fn );
    push( @res, $fn              ) if( -f $fn && $fn =~ /\.desktop$/i );
  } 
  return @res;
}

#

PO_betoltes( 'comment.po', 'Comment'     );
PO_betoltes( 'generic.po', 'GenericName' );
PO_betoltes( 'name.po',    'Name'        );

my @files = file_list('.');
while( my $fn = shift(@files) ){
  open( IN, '<:raw', $fn );
  my $szoveg = join( '', <IN> );
  close(IN);

  my @szoveg = split( /(^\[.*\])/, $szoveg );

  shift(@szoveg) if( length($szoveg[0]) < 1 );
  my $valtozott = 0;
  foreach $szoveg ( @szoveg ){
    foreach my $mezo ( keys %forditas ){
      foreach my $msgid ( keys %{$forditas{$mezo}} ){
        if( $szoveg =~ /\Q${mezo}=$msgid\E/im  &&
            $szoveg !~ /\Q${mezo}[hu]=\E/im        ){
          $szoveg =~ s/(\Q${mezo}=$msgid\E)/$1\n${mezo}[hu]=$forditas{$mezo}{$msgid}/im;
          $valtozott = 1;
        }
      }
    }
  }

  if( $valtozott ){
    printf "forditas: $fn\n";
    open( OUT, '>:raw', $fn ); binmode(OUT);
    print OUT join( '', @szoveg );
    close(OUT);
  }
}

A három .po fájlból összeállít egy belső "szótárat", és végignézi a .desktop fájlokat, hogy lát-e bennük a szótárban szereplő még nem lefordított szöveget.

Mivel felülírja a .desktop fájlokat, ezért óvatosan kezelendő!