( ggallo | 2021. 06. 20., v – 19:31 )

Tehát akkor van két router, összekotve, VLAN 100 mindkettőn elérhető, és mindkettőn van egy-egy DHCP szerver, ami a VLAN 100-ban pontosan ugyan abból az IP tartományból oszt címeket. Ergo VLAN 100-ban minden IP címből lehet kettő egy időben. Hát, mondjuk úgy, ez így nem az igazi...

Ha mindenképp szükséges a két DHCP szerver (készülsz arra, hogy elmúlik a két router közötti kapcsolat), akkor legalább oszd ketté az IP tarományt, és az egyik fele legyen az egyik router-en, a másik fele legyen a másik router-en. Így legalább nem lesz IP cím ütközés (igaz, a router-ek kapcsolatának elveszésekor internet nem lesz a 2. router-re kötött eszközökön, de egymással legalább tudnak beszélni addig is).

Ha nem kell a kapcsolat megszakadásával számolni, akkor elég a router 1-en a DHCP szerver, a router 2 gépei a VLAN 100 kapcsolaton keresztül ugyan úgy fognak IP címet kapni.

Viszont így ez a konfig egy tákolás, semmilyen MT ajánlást vagy leírást nem követ, csak addig nyomogattad, míg elérted egyik oldalról a másikat...

 

De, hogy ne csak sima trollnak tűnjek:

Szerintem úgy kellene csinálnod (és mindenki másnak is, aki itt megosztott konfig részletet), hogy 1 bridge van, VLAN filtering engedélyezve. A VLAN-ok definiálva, hozzájuk megadva fixen a trunk portok amik több VLAN-on forgalmaznak, az access portoknél pedig PVID-vel kerülnek a megfelelő VLAN-ba.

/interface bridge
add name=bridge vlan-filtering=yes
/interface bridge port
add bridge=bridge interface=ether2
add bridge=bridge interface=ether3 pvid=100
add bridge=bridge interface=ether4 pvid=100
add bridge=bridge interface=ether5 pvid=200
add bridge=bridge interface=wlan1 pvid=250
add bridge=bridge interface=wlan2 pvid=250
/interface bridge vlan
add bridge=bridge untagged=bridge vlan-ids=1
add bridge=bridge tagged=bridge,ether2 vlan-ids=100
add bridge=bridge tagged=bridge,ether2 vlan-ids=200
add bridge=bridge tagged=bridge,ether2 vlan-ids=250

A router elérése és pl. DHCP szerver működtetése pedig ebben a felállásban a bridge-re ültetett VLAN interfészeken történik:

/interface vlan
add interface=bridge name=vlan100 vlan-id=100
add interface=bridge name=vlan200 vlan-id=200
add interface=bridge name=vlan250 vlan-id=250
/ip address
add address=192.168.100.254/24 interface=vlan100
add address=192.168.200.254/24 interface=vlan200
add address=192.168.250.254/24 interface=vlan250
/ip pool
add name=pool-vlan100 ranges=192.168.100.32-192.168.100.223
add name=pool-vlan200 ranges=192.168.200.32-192.168.200.223
add name=pool-vlan250 ranges=192.168.250.32-192.168.250.223
/ip dhcp-server
add address-pool=pool-vlan100 disabled=no interface=vlan100 name=dhcp-vlan100
add address-pool=pool-vlan200 disabled=no interface=vlan200 name=dhcp-vlan200
add address-pool=pool-vlan200 disabled=no interface=vlan250 name=dhcp-vlan250
/ip dhcp-server network
add address=192.168.100.0/24 dns-server=192.168.100.254 gateway=192.168.100.254
add address=192.168.200.0/24 dns-server=192.168.200.254 gateway=192.168.200.254
add address=192.168.250.0/24 dns-server=192.168.250.254 gateway=192.168.250.254

Ez a konfiguráció működik attól függetlenül, hogy milyen a switch chip, mit tud az adott eszköz offload-olni vagy mit nem. Ha ilyen módon tanulod meg a MT VLAN-ozást, akkor egységesen, minden eszközön a legjobb teljesítményt elérve tudod használni azt.

A második router-re értelem szerűen nem kellenek a DHCP szerver részek, és nyilván más IP címet kell megadni abban az egy VLAN-ban, ahol el szeretnéd érni (a második eszköznek nem kell IP címének lennie az összes VLAN-ban, arra csak azon az eszközön van szükség, amit router funkciót is ellát).

Ha valami nem stimmel, írd meg, fejből írtam a konfigot, nem pötyögtem be két eszközbe.