bash: email subject dekódolás?

Pedig a munpack elvben jo lenne erre, reszlet a man-jabol:

“

To decode a MIME message, first save it to a text file.  If possible,  save  it  with  all
       headers  included.   Munpack  can  decode  some MIME files when the headers are missing or
       incomplete, other files it cannot decode without having the information  in  the  headers.
       In  general, messages which have a statement at the beginning that they are in MIME format
       can be decoded without the headers.  Messages which have been split  into  multiple  parts
       generally require all headers in order to be reassembled and decoded.”

kb. 4-5 sorosat.

Fentebb linkelték az RFC2047-et, abban részletesen le van írva, de a lényeg a következő:

An "encoded-word" is a sequence of printable ASCII characters that begins with "=?", ends with "?=", and has two "?"s in between. It specifies a character set and an encoding method, and also includes the original text encoded as graphic ASCII characters, according to the rules for that encoding method.

Nehezítésképpen egy mező (pl. Subject) több soros is lehet, és ahogy nálad is, váltakozhat benne a kódolt és kódolatlan szöveg. Valamikor nagyon régen írtam egy awk szkriptet, ami szépen lekezel minden lehetőséget, most megosztom veled:

BEGIN {
  RS="\r?\n"
  FS=":"
  AddLine=0
}

$0~"^$" || AddLine==1 && $0!~"^[ \t]+" {
  exit 0
}

AddLine==0 {
  if (tolower($1)==tolower(HeaderField)) {
    $0=substr($0,index($0,":")+1)
    sub("^ *","")
    AddLine=1
  }
}

AddLine==1 {
  sub("^[ \t]+","")
  sub("[ \t]+$","")
  LineBuffer=LineBuffer sep $0
  sep=" "
}

END {
  gsub("\?=[ \t]+=\?","?==?",LineBuffer)
  DecodedLine=""
  while (LineBuffer!="") {
    QWordStartOffset=index(LineBuffer,"=?")
    if (QWordStartOffset==0) {
      DecodedLine=DecodedLine LineBuffer
      break
    }
    else {
      DecodedLine=DecodedLine substr(LineBuffer,1,QWordStartOffset-1)
    LineBuffer=substr(LineBuffer,QWordStartOffset)
    TempLineBuffer=LineBuffer
    Offset=index(TempLineBuffer,"?")
    QWordLength=Offset
    if (Offset==0) {
      DecodedLine=DecodedLine LineBuffer
      break
    }
    TempLineBuffer=substr(TempLineBuffer,Offset+1)
    Offset=index(TempLineBuffer,"?")
    QWordLength+=Offset
    if (Offset==0) {
      DecodedLine=DecodedLine LineBuffer
      break
    }
    TempLineBuffer=substr(TempLineBuffer,Offset+1)
    Offset=index(TempLineBuffer,"?")
    QWordLength+=Offset
    if (Offset==0) {
      DecodedLine=DecodedLine LineBuffer
      break
    }
    TempLineBuffer=substr(TempLineBuffer,Offset+1)
    Offset=index(TempLineBuffer,"?=")
    QWordLength+=Offset+1
    if (Offset!=0) {
      QWord=substr(LineBuffer,1,QWordLength)
      split(QWord,QWordElements,"\?")
      Charset=QWordElements[2]
      Encoding=toupper(QWordElements[3])
      QWordText=QWordElements[4]
      if (Encoding=="Q") {
        gsub("_","\x20",QWordText)
        cmd="echo \"" QWordText "\" | recode -fq \"" Charset "\"/quoted-printable..\"" OutputCharset "\""
        cmd | getline DecodedQWord
        close (cmd)
      }
      else if (Encoding=="B") {
        cmd="echo \"" QWordText "\" | recode -fq \"" Charset "\"/base64..\"" OutputCharset "\""
        cmd | getline DecodedQWord
        close (cmd) } else DecodedQWord=QWord
        DecodedLine=DecodedLine DecodedQWord
        LineBuffer=substr(LineBuffer,QWordLength+1)
      }
      else {
        DecodedLine=DecodedLine LineBuffer
        break
      }
    }
  }
  sub("^[ \t]+","",DecodedLine)
  sub("[ \t]+$","",DecodedLine)
  printf "%s\n",DecodedLine
}

Demo egy valódi levéllel:

Subject: =?iso-8859-2?Q?HPE_Webinar_megh=EDv=F3:_Automatiz=E1ci=F3_avagy_=FCzemelt?=
  =?iso-8859-2?Q?et=E9s_a_kanap=E9r=F5l_/_=E1prilis_09._cs=FCt=F6rt=F6k_09:?=
  =?iso-8859-2?Q?30?=

$ awk -v HeaderField="Subject" -v OutputCharset="$(locale charmap)" -f get-header-field.awk test.eml
HPE Webinar meghívó: Automatizáció avagy üzemeltetés a kanapéről / április 09. csütörtök 09:30

Jó, de nem perlben írsz azt el is lehet olvasni legközelebb ;)